include(FindGettext)

set(ADDRESS_BOOK_APP_ICON "lomiri-addressbook-app.svg")
set(ADDRESS_BOOK_APP_SPLASH "lomiri-addressbook-app-splash.svg")
set(ADDRESS_BOOK_APP_SYMBOLIC_ICON "lomiri-addressbook-app-symbolic.svg")
set(ADDRESS_BOOK_ARTWORK_PATH "${ADDRESS_BOOK_APP_FULL_DIR}/artwork")

if(NOT CLICK_MODE)
    set(XSCREENSHOT "X-Screenshot=${ADDRESS_BOOK_ARTWORK_PATH}/lomiri-addressbook-app-preview.png")
endif()

configure_file(${DESKTOP_FILE}.in.in ${DESKTOP_FILE}.in)
add_custom_target(${DESKTOP_FILE} ALL
    COMMENT "Merging translations into ${DESKTOP_FILE}..."
    COMMAND ${GETTEXT_MSGFMT_EXECUTABLE}
            --desktop --template=${CMAKE_CURRENT_BINARY_DIR}/${DESKTOP_FILE}.in
            -o ${DESKTOP_FILE}
            -d ${CMAKE_SOURCE_DIR}/po
)

if(CLICK_MODE)
    install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${DESKTOP_FILE}
        DESTINATION ${CMAKE_INSTALL_BINDIR}
    )
else()
    install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${DESKTOP_FILE}
        DESTINATION ${CMAKE_INSTALL_DATADIR}/applications
    )
endif()

install(FILES "lomiri-addressbook-app.url-dispatcher"
    DESTINATION ${CMAKE_INSTALL_DATADIR}/lomiri-url-dispatcher/urls
)
